Writing indicators in WickScript

indicator "Name" on chart     # in the price chart, on the price scale (also the default without on chart)
indicator "Name" in pane      # in its own panel below the chart, with a Height setting

wickscript 1
indicator "RSI with levels" in pane
period = input 14 "Period" from 2 to 50
r = rsi(close, period)
show r as line "RSI" color violet
show 70 as line "Overbought" color red
show 30 as line "Oversold" color green
show r crosses below 30 as event "Into oversold"

wickscript 1
indicator "Inside bars" on chart
inside = high < high[1] and low > low[1]
motherHigh = na
motherLow = na
if inside then
    motherHigh = high[1]
    motherLow = low[1]
end
show motherHigh as line "Mother high" color green
show motherLow as line "Mother low" color red
when inside
    mark "IB" above color gray
end

wickscript 1
indicator "Keltner channel" on chart
length = input 20 "Length" from 10 to 50 step 10
mult = input 2 "ATR multiple" from 1 to 3 step 0.5
tone = input color teal "Color"
basis = ema(close, length)
show basis as line "Basis" color tone
show basis + mult * atr(length) as line "Upper" color tone
show basis - mult * atr(length) as line "Lower" color tone

wickscript 1
indicator "Volume spikes" on chart
avg = sma(volume, input 20 "Average length")
spike = volume > 3 * avg
when spike
    mark "VOL" above color amber
    level close "Spike close" color amber until killed or 50 bars
    alert "Volume spike"
end
hud "Volume {volume / avg} × average · last spike {bars since spike} bars ago"

use indicator "Name" [with setting value, setting value …] as alias

wickscript 1
indicator "MACD from the list" in pane
fast = input 8 "Fast"
use indicator "MACD" with fastPeriod fast, slowPeriod 21 as m
use indicator "RSI" with period 21 as r
show m.histogram as histogram "MACD histogram"
show m.histogram crosses above 0 and r.value > 50 as event "Momentum up"

wickscript 1
indicator "Relative Strength Index" in pane
period = input 14 "Period" from 2 to 500
show rsi(close, period) as line "RSI" color violet

wickscript 1
indicator "MACD" in pane
fastPeriod = input 12 "Fast period" from 1 to 500
slowPeriod = input 26 "Slow period" from 1 to 1000
signalPeriod = input 9 "Signal period" from 1 to 500
m = macd(close, fastPeriod, slowPeriod, signalPeriod)
show m.line as line "MACD" color blue
show m.signal as line "Signal" color amber
show m.histogram as histogram "Histogram"

wickscript 1
indicator "Stochastic" in pane
period = input 9 "%K period" from 1 to 500
periodSmooth = input 1 "%K smoothing" from 1 to 100
periodD = input 3 "%D period" from 1 to 100
s = stoch(period, periodSmooth, periodD)
show s.k as line "%K" color blue
show s.d as line "%D" color amber

wickscript 1
indicator "Stochastic Momentum Index" in pane
period = input 10 "Period" from 2 to 500
# high and low of the previous candles (without the current one), distance to the middle relative to the whole range
hh = highest(high, period)[1]
ll = lowest(low, period)[1]
show 100 * ((close - (hh + ll) / 2) / (hh - ll)) as line "SMI" color violet

wickscript 1
indicator "VWAP" on chart
vwapUnit = input choice "Anchor" of ["day", "week", "month", "hour", "minute", "session"]
vwapUnitAmount = input 1 "Anchor amount" from 1 to 100
show vwap(vwapUnit, vwapUnitAmount) as line "VWAP" color violet

wickscript 1
indicator "Bollinger Bands" on chart
length = input 20 "Length" from 5 to 100 step 5
mult = input 2 "Deviations" from 1 to 3 step 0.5
basis = sma(close, length)
dev = mult * stdev(close, length)
show basis as line "Basis" color amber
show basis + dev as line "Upper" color blue
show basis - dev as line "Lower" color blue
show close crosses above basis + dev as event "Break up"

wickscript 1
indicator "Previous day high and low" on chart
pdh = high on 1d
pdl = low on 1d
show pdh as line "PDH" color green
show pdl as line "PDL" color red
when high > pdh
    mark "PDH swept" above color orange
end

wickscript 1
indicator "Delta and CVD" in pane
show delta as histogram "Delta"
show cvd - ema(cvd, 50) as line "CVD vs. its EMA" color cyan